mirror of
https://github.com/torvalds/linux.git
synced 2026-05-12 16:18:45 +02:00
23ef9d4397
The kernel's CFI implementation uses the KCFI ABI specifically, and is not strictly tied to a particular compiler. In preparation for GCC supporting KCFI, rename CONFIG_CFI_CLANG to CONFIG_CFI (along with associated options). Use new "transitional" Kconfig option for old CONFIG_CFI_CLANG that will enable CONFIG_CFI during olddefconfig. Reviewed-by: Linus Walleij <linus.walleij@linaro.org> Reviewed-by: Nathan Chancellor <nathan@kernel.org> Link: https://lore.kernel.org/r/20250923213422.1105654-3-kees@kernel.org Signed-off-by: Kees Cook <kees@kernel.org>
63 lines
1.5 KiB
ArmAsm
63 lines
1.5 KiB
ArmAsm
/* SPDX-License-Identifier: GPL-2.0-only */
|
|
/*
|
|
* linux/arch/arm/mm/tlbv4.S
|
|
*
|
|
* Copyright (C) 1997-2002 Russell King
|
|
*
|
|
* ARM architecture version 4 TLB handling functions.
|
|
* These assume a split I/D TLBs, and no write buffer.
|
|
*
|
|
* Processors: ARM720T
|
|
*/
|
|
#include <linux/linkage.h>
|
|
#include <linux/init.h>
|
|
#include <linux/cfi_types.h>
|
|
#include <asm/assembler.h>
|
|
#include <asm/asm-offsets.h>
|
|
#include <asm/tlbflush.h>
|
|
#include "proc-macros.S"
|
|
|
|
.align 5
|
|
/*
|
|
* v4_flush_user_tlb_range(start, end, mm)
|
|
*
|
|
* Invalidate a range of TLB entries in the specified user address space.
|
|
*
|
|
* - start - range start address
|
|
* - end - range end address
|
|
* - mm - mm_struct describing address space
|
|
*/
|
|
.align 5
|
|
SYM_TYPED_FUNC_START(v4_flush_user_tlb_range)
|
|
vma_vm_mm ip, r2
|
|
act_mm r3 @ get current->active_mm
|
|
eors r3, ip, r3 @ == mm ?
|
|
retne lr @ no, we dont do anything
|
|
.v4_flush_kern_tlb_range:
|
|
bic r0, r0, #0x0ff
|
|
bic r0, r0, #0xf00
|
|
1: mcr p15, 0, r0, c8, c7, 1 @ invalidate TLB entry
|
|
add r0, r0, #PAGE_SZ
|
|
cmp r0, r1
|
|
blo 1b
|
|
ret lr
|
|
SYM_FUNC_END(v4_flush_user_tlb_range)
|
|
|
|
/*
|
|
* v4_flush_kern_tlb_range(start, end)
|
|
*
|
|
* Invalidate a range of TLB entries in the specified kernel
|
|
* address range.
|
|
*
|
|
* - start - virtual address (may not be aligned)
|
|
* - end - virtual address (may not be aligned)
|
|
*/
|
|
#ifdef CONFIG_CFI
|
|
SYM_TYPED_FUNC_START(v4_flush_kern_tlb_range)
|
|
b .v4_flush_kern_tlb_range
|
|
SYM_FUNC_END(v4_flush_kern_tlb_range)
|
|
#else
|
|
.globl v4_flush_kern_tlb_range
|
|
.equ v4_flush_kern_tlb_range, .v4_flush_kern_tlb_range
|
|
#endif
|